das entspricht weitestgehend meinem obigen Script. Aber die enthaltenen Dateien sind weitestgehend veraltet. Würde ich nicht machen!

Ich habe um den Store zu installieren dieses Script genutzt:
https://github.com/megakarlach/LTSC-Add-MicrosoftStore-2021

Bei Windows 11 IoT LTSC, welches ich auch mal testweise installiert hatte reichte dagegen ein wsreset -i

[quote=Arquez post_id=458066 time=1779451312 user_id=52778]
( 62 Einzel-Links :betruebt: )
[/quote]

nee, sind nicht 62. Immer nur die neuesten und nur die .appx Dateien, bzw. beim Store die .msixbundle

Ja, hatte ich auch gemacht. Sind ja nur zwei Apps, die man benötigt. "Store" und "Windows Package Manager". Macht alles etwas einfacher, wenn man Sachen aus dem Store installieren möchte. Weiß bloß nicht, ob Microsoft da wieder etwas am Store geändert ha, so dass man ein Microsoft Konto dafür benötigt. Da ich eines habe, habe ich das bislang nicht ohne Microsoft Konto getestet.

Hab ich gemacht, die App erscheint auch bei den installierten Programmen. Aber wenn man draufklickt, passiert nichts. Vielleicht muß ich doch diesen bescheuerten Store installieren ( 62 Einzel-Links :betruebt: )

Du müsstest dir von der Webseite die "Nummer" kopieren und bei Adguard auf ID umstellen, wie Holgi es über dir gezeigt hat. Dann kannst du Apps auch ohne Store installieren

wsreset.exe -i und Neustart hab ich gemacht, kein Unterschied. Aber ich habe auch keinen Store installiert (bisher). Dass das mit workarounds möglich ist, ist mir klar. Meine Frage war nur, ob es auch ohne Store möglich ist. Den brauch ich sonst nie.

Stand 28.10.25

Microsoft.WindowsStore_22408.1401.6.0_neutral_~_8wekyb3d8bbwe.msixbundle
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x86__8wekyb3d8bbwe.Appx
Microsoft.WindowsStore_22509.1401.11.0_neutral_~_8wekyb3d8bbwe.Msixbundle
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x64__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x86__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x64__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x86__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.8_8.2501.31001.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.8_8.2501.31001.0_x86__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x86__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00_14.0.33519.0_x64__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00_14.0.33519.0_x86__8wekyb3d8bbwe.Appx

@setlocal DisableDelayedExpansion
@echo off
set "SysPath=%SystemRoot%\System32"
if exist "%SystemRoot%\Sysnative\reg.exe" (set "SysPath=%SystemRoot%\Sysnative")
set "Path=%SysPath%;%SystemRoot%;%SysPath%\Wbem;%SystemRoot%\System32\WindowsPowerShell\v1.0\"
set "_err===== ERROR ===="
set "_lin============================================================="

for /f "tokens=6 delims=[]. " %%# in ('ver') do if %%# lss 18362 goto :version
reg query HKU\S-1-5-19 1>nul 2>nul || goto :uac

if /i "%PROCESSOR_ARCHITECTURE%"=="arm64" goto :noarm
if /i "%PROCESSOR_ARCHITEW6432%"=="arm64" goto :noarm
set "xOS=x64"
if /i "%PROCESSOR_ARCHITECTURE%"=="x86" (if not defined PROCESSOR_ARCHITEW6432 set "xOS=x86")
set "_work=%~dp0"
set "_work=%_work:~0,-1%"
setlocal EnableDelayedExpansion
pushd "!_work!"
if not exist "*WindowsStore*.*xbundle" goto :nofiles
if not exist "*WindowsStore*.xml" goto :nofiles

for %%# in (
Store PurchaseApp AppInstaller XboxIdentity
NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 VCDX64 VCDX86 XM27X64 XM27X86 XM26X64 XM26X86
) do (
set "%%#="
)

for /f %%i in ('dir /b *WindowsStore*.*xbundle 2^>nul') do set "Store=%%i"
call :detect NET.Native.Framework.2.2 NF22
call :detect NET.Native.Runtime.2.2 NR22
call :detect VCLibs.140.00_ VCP
call :detect VCLibs.140.00.UWPDesktop VCD
call :detect Microsoft.UI.Xaml.2.8 XM28
call :detect Microsoft.UI.Xaml.2.4 XM24
goto :proceed

:detect
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x64"') do set "%2X64=%%i"
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x86"') do set "%2X86=%%i"
goto :eof

:proceed
if /i %xOS%==x64 (
for %%# in (NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 XM28X64 XM28X86) do (if not defined %%# goto :nofiles)
) else (
for %%# in (NF22X86 NR22X86 VCPX86 XM28X86) do (if not defined %%# goto :nofiles)
)

if exist "*StorePurchaseApp*.*xbundle" if exist "*StorePurchaseApp*.xml" (
for /f %%i in ('dir /b *StorePurchaseApp*.*xbundle 2^>nul') do set "PurchaseApp=%%i"
)
if exist "*XboxIdentityProvider*.*xbundle" if exist "*XboxIdentityProvider*.xml" (
for /f %%i in ('dir /b *XboxIdentityProvider*.*xbundle 2^>nul') do set "XboxIdentity=%%i"
)
if exist "*DesktopAppInstaller*.*xbundle" if exist "*DesktopAppInstaller*.xml" (
for /f %%i in ('dir /b *DesktopAppInstaller*.*xbundle 2^>nul') do set "AppInstaller=%%i"
)

if /i %xOS%==x64 (
for %%# in (VCDX64 VCDX86 XM24X64 XM24X86) do (if not defined %%# set "AppInstaller=")
) else (
for %%# in (VCDX86 XM24X86) do (if not defined %%# set "AppInstaller=")
)

if /i %xOS%==x64 (
set "DepStore=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%,%XM28X64%,%XM28X86%"
set "DepInstaller=%VCDX64%,%VCDX86%,%XM24X64%,%XM24X86%"
set "DepPurchase=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
set "DepXbox=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
) else (
set "DepStore=%NF22X86%,%NR22X86%,%VCPX86%,%XM28X86%"
set "DepInstaller=%VCDX86%,%XM24X86%"
set "DepPurchase=%NF22X86%,%NR22X86%,%VCPX86%"
set "DepXbox=%NF22X86%,%NR22X86%,%VCPX86%"
)

set "_psc=PowerShell -NoLogo -NoProfile -NonInteractive -InputFormat None -ExecutionPolicy Bypass"

echo.
echo %_lin%
echo Adding Microsoft Store
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %Store% -DependencyPackagePath %DepStore% -LicensePath Microsoft.WindowsStore_8wekyb3d8bbwe.xml
for %%i in (%DepStore%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %Store%

if defined PurchaseApp (
echo.
echo %_lin%
echo Adding Store Purchase App
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %PurchaseApp% -DependencyPackagePath %DepPurchase% -LicensePath Microsoft.StorePurchaseApp_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %PurchaseApp%
)

if defined XboxIdentity (
echo.
echo %_lin%
echo Adding Xbox Identity Provider
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %XboxIdentity% -DependencyPackagePath %DepXbox% -LicensePath Microsoft.XboxIdentityProvider_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %XboxIdentity%
)

if defined AppInstaller (
echo.
echo %_lin%
echo Adding App Installer
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %AppInstaller% -DependencyPackagePath %DepInstaller% -LicensePath Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.xml
for %%i in (%DepInstaller%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %AppInstaller%
)

echo.
echo Done
goto :fin

:noarm
echo %_err%
echo Windows 10 ARM64 is not supported
goto :fin

:uac
echo %_err%
echo Run the script as administrator
goto :fin

:version
echo %_err%
echo This pack is for Windows 10 build 18362 and later
goto :fin

:nofiles
echo %_err%
echo Required files are missing in the current directory

:fin
echo.
echo Press any key to exit.
pause >nul
goto :eof

oder selbst erledigen:
[url]https://store.rg-adguard.net/[/url] aufrufen und als Id 9WZDNCRFJBMP vorgeben (Retail).
dort die Dateien für die Framework herunerladen:
X86 und X64 (kein ARM, kein ARM64)
Stand 10/25 war das bei mir:
[code]Stand 28.10.25

Microsoft.WindowsStore_22408.1401.6.0_neutral_~_8wekyb3d8bbwe.msixbundle
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x86__8wekyb3d8bbwe.Appx
Microsoft.WindowsStore_22509.1401.11.0_neutral_~_8wekyb3d8bbwe.Msixbundle
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x64__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x86__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x64__8wekyb3d8bbwe.Appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x86__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.8_8.2501.31001.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.8_8.2501.31001.0_x86__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x86__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00_14.0.33519.0_x64__8wekyb3d8bbwe.Appx
Microsoft.VCLibs.140.00_14.0.33519.0_x86__8wekyb3d8bbwe.Appx[/code]

sind jetzt natürlich andere.
dann noch dieses Script:
Add-Store.cmd
[code]@setlocal DisableDelayedExpansion
@echo off
set "SysPath=%SystemRoot%\System32"
if exist "%SystemRoot%\Sysnative\reg.exe" (set "SysPath=%SystemRoot%\Sysnative")
set "Path=%SysPath%;%SystemRoot%;%SysPath%\Wbem;%SystemRoot%\System32\WindowsPowerShell\v1.0\"
set "_err===== ERROR ===="
set "_lin============================================================="

for /f "tokens=6 delims=[]. " %%# in ('ver') do if %%# lss 18362 goto :version
reg query HKU\S-1-5-19 1>nul 2>nul || goto :uac

if /i "%PROCESSOR_ARCHITECTURE%"=="arm64" goto :noarm
if /i "%PROCESSOR_ARCHITEW6432%"=="arm64" goto :noarm
set "xOS=x64"
if /i "%PROCESSOR_ARCHITECTURE%"=="x86" (if not defined PROCESSOR_ARCHITEW6432 set "xOS=x86")
set "_work=%~dp0"
set "_work=%_work:~0,-1%"
setlocal EnableDelayedExpansion
pushd "!_work!"
if not exist "*WindowsStore*.*xbundle" goto :nofiles
if not exist "*WindowsStore*.xml" goto :nofiles

for %%# in (
Store PurchaseApp AppInstaller XboxIdentity
NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 VCDX64 VCDX86 XM27X64 XM27X86 XM26X64 XM26X86
) do (
set "%%#="
)

for /f %%i in ('dir /b *WindowsStore*.*xbundle 2^>nul') do set "Store=%%i"
call :detect NET.Native.Framework.2.2 NF22
call :detect NET.Native.Runtime.2.2 NR22
call :detect VCLibs.140.00_ VCP
call :detect VCLibs.140.00.UWPDesktop VCD
call :detect Microsoft.UI.Xaml.2.8 XM28
call :detect Microsoft.UI.Xaml.2.4 XM24
goto :proceed

:detect
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x64"') do set "%2X64=%%i"
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x86"') do set "%2X86=%%i"
goto :eof

:proceed
if /i %xOS%==x64 (
for %%# in (NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 XM28X64 XM28X86) do (if not defined %%# goto :nofiles)
) else (
for %%# in (NF22X86 NR22X86 VCPX86 XM28X86) do (if not defined %%# goto :nofiles)
)

if exist "*StorePurchaseApp*.*xbundle" if exist "*StorePurchaseApp*.xml" (
for /f %%i in ('dir /b *StorePurchaseApp*.*xbundle 2^>nul') do set "PurchaseApp=%%i"
)
if exist "*XboxIdentityProvider*.*xbundle" if exist "*XboxIdentityProvider*.xml" (
for /f %%i in ('dir /b *XboxIdentityProvider*.*xbundle 2^>nul') do set "XboxIdentity=%%i"
)
if exist "*DesktopAppInstaller*.*xbundle" if exist "*DesktopAppInstaller*.xml" (
for /f %%i in ('dir /b *DesktopAppInstaller*.*xbundle 2^>nul') do set "AppInstaller=%%i"
)

if /i %xOS%==x64 (
for %%# in (VCDX64 VCDX86 XM24X64 XM24X86) do (if not defined %%# set "AppInstaller=")
) else (
for %%# in (VCDX86 XM24X86) do (if not defined %%# set "AppInstaller=")
)

if /i %xOS%==x64 (
set "DepStore=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%,%XM28X64%,%XM28X86%"
set "DepInstaller=%VCDX64%,%VCDX86%,%XM24X64%,%XM24X86%"
set "DepPurchase=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
set "DepXbox=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
) else (
set "DepStore=%NF22X86%,%NR22X86%,%VCPX86%,%XM28X86%"
set "DepInstaller=%VCDX86%,%XM24X86%"
set "DepPurchase=%NF22X86%,%NR22X86%,%VCPX86%"
set "DepXbox=%NF22X86%,%NR22X86%,%VCPX86%"
)

set "_psc=PowerShell -NoLogo -NoProfile -NonInteractive -InputFormat None -ExecutionPolicy Bypass"

echo.
echo %_lin%
echo Adding Microsoft Store
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %Store% -DependencyPackagePath %DepStore% -LicensePath Microsoft.WindowsStore_8wekyb3d8bbwe.xml
for %%i in (%DepStore%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %Store%

if defined PurchaseApp (
echo.
echo %_lin%
echo Adding Store Purchase App
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %PurchaseApp% -DependencyPackagePath %DepPurchase% -LicensePath Microsoft.StorePurchaseApp_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %PurchaseApp%
)

if defined XboxIdentity (
echo.
echo %_lin%
echo Adding Xbox Identity Provider
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %XboxIdentity% -DependencyPackagePath %DepXbox% -LicensePath Microsoft.XboxIdentityProvider_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %XboxIdentity%
)

if defined AppInstaller (
echo.
echo %_lin%
echo Adding App Installer
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %AppInstaller% -DependencyPackagePath %DepInstaller% -LicensePath Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.xml
for %%i in (%DepInstaller%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %AppInstaller%
)

echo.
echo Done
goto :fin

:noarm
echo %_err%
echo Windows 10 ARM64 is not supported
goto :fin

:uac
echo %_err%
echo Run the script as administrator
goto :fin

:version
echo %_err%
echo This pack is for Windows 10 build 18362 and later
goto :fin

:nofiles
echo %_err%
echo Required files are missing in the current directory

:fin
echo.
echo Press any key to exit.
pause >nul
goto :eof[/code]
und die angehängte Datei Microsoft.WindowsStore_8wekyb3d8bbwe.xml
Alles in einen Ordner und das Script Add-Store.cmd ausführen.
[attachment=1]Microsoft.WindowsStore_8wekyb3d8bbwe.xml[/attachment]
[attachment=0]Add-Store.zip[/attachment]

Viel Spaß!

[quote=DK2000 post_id=458054 time=1779445939 user_id=39966]
Holgi weiß bestimmt, wo es den gibt.
[/quote]

klar weiß der Holgi das:
[url]https://forums.mydigitallife.net/threads/guide-add-store-to-windows-10-11-enterprises-sku-ltsb-ltsc.70741/[/url]
[url]https://forums.mydigitallife.net/threads/guide-add-store-to-windows-10-11-enterprises-sku-ltsb-ltsc.70741/page-30#post-1468779[/url]

Fehlt wohl der Store. Der Browser leitet i.d.R. auch nur zum Store weiter.

Ob [i]wsreset.exe /i [/i] alleine funktioniert, weiß ich nicht. Setzt aber auch voraus, dass der [i]Windows Package Manager[/i] installiert ist, da über diesen letztendlich die Installation der Pakete stattfinden.

Gab doch hier irgendwo ein Paket mit Skript und allen Komponenten, welche benötigt werden, damit der Store mit der LTSC funktioniert. Holgi weiß bestimmt, wo es den gibt.

wsreset.exe -i

[code]wsreset.exe -i[/code] in einer Kommandzeile und danach Neustart hast du schon gemacht?

Hi, ich habe das Problem, daß ich über den MS Store im Browser viele Apps nicht downloaden kann, er versucht zu starten und bricht ab mit Fehler 0x80070426. Das passiert offenbar bei Apps, bei denen nicht direkt die App, sondern vorab ein Installer runtergeladen werden.
Gibt es da einen Trick, wie man die App trotzdem runterladen kann, oder muß man auf jeden Fall den Store nachinstallieren?

Die IoT+LTSC.19044.7291 ISO ist fertig :)

[quote=MaggusHVN post_id=457560 time=1777974815 user_id=53692]
..., ändert sich die Edition auf "Windows 10 Enterprise LTSC".
Ich gehe davon aus, dass da was nicht richtig ist. Wenn ich alles richtig gelesen habe, hat die "Win 10 Ent LTSC" nur 5 Jahre erweiterten support anstatt der 10 Jahre, ist das korrekt?
...
[/quote]
Ohne hier Werbung machen zu wollen, aber hier ist das kurzgefasst...[url]https://www.sunany.com/de/whats-the-difference-between-windows-10-iot-enterprise-and-ltsc.html[/url]
Oder man ackert sich bei MS durch: [url]https://learn.microsoft.com/de-de/windows/iot/iot-enterprise/whats-new/windows-10-iot-enterprise-ltsc-2021[/url]

alles korrekt! Key reklamieren. Viel Glück!