Deskmodder.de

Code: Alles auswählen

.\Make2023BootableMedia.ps1 -MediaPath "Unbreaked_26200.8728_USERASK_25H2_GE_RELEASE_XXXL_SUPERMULTI_X64FRE_DE.ISO" -TargetType ISO -ISOPath "Unbreaked_26200.8728_USERASK_25H2_GE_RELEASE_XXXL_SUPERMULTI_X64FRE_DE-CA2023.ISO"

Code: Alles auswählen

@echo off
setlocal EnableDelayedExpansion

set "WORKDIR=%~dp0"
set "MYTEMP=%WORKDIR%TMP"
set "RUNNER=%WORKDIR%Run_CA2023.ps1"

if not exist "%MYTEMP%" mkdir "%MYTEMP%"

set COUNT=0

for %%I in ("%WORKDIR%*.iso") do (
    set /a COUNT+=1
    set "SOURCEISO=%%~fI"
    set "TARGETISO=%%~dpnI-CA2023%%~xI"
)

if !COUNT! EQU 0 (
    echo Keine ISO-Datei gefunden.
    pause
    exit /b 1
)

if !COUNT! GTR 1 (
    echo Es wurde mehr als eine ISO-Datei gefunden.
    echo Bitte nur eine ISO im Verzeichnis belassen.
    pause
    exit /b 1
)

echo Quell-ISO:
echo !SOURCEISO!
echo.
echo Ziel-ISO:
echo !TARGETISO!
echo.

rem Hilfs-PowerShell-Datei erzeugen
(
echo $env:TEMP = '%MYTEMP%'
echo $env:TMP  = '%MYTEMP%'
echo Set-Location '%WORKDIR%'
echo ^& '%WORKDIR%Make2023BootableMedia.ps1' -MediaPath '%SOURCEISO%' -TargetType ISO -ISOPath '%TARGETISO%'
) > "%RUNNER%"

powershell.exe -NoProfile -ExecutionPolicy Bypass -Command ^
 "Start-Process powershell.exe -Verb RunAs -Wait -WorkingDirectory '%WORKDIR%' -ArgumentList '-NoProfile -ExecutionPolicy Bypass -File ""%RUNNER%""'"

echo.
echo Fertig.
pause